Symbolic Linear Circuit Analysis of a negative-feedback system

SLiCAP can evaluate the behavior of negative feedback systems, both on system and on circuit level. This example shows how to evaluate the dynamic behavior with both root-locus techniques and with phase-margin.
[Passive dynamic circuit for <em>SLiCAP</em>]
(a) Negative feedback system for analysis with SLiCAP.
(b) SLiCAP input circuit of the negative feedback system.
Netlist

Root-locus study
*****************************************************************************
* definition of the input (source)                                          *
*****************************************************************************
V_in in 0 1
.s V_in
*****************************************************************************
* definition of the transfer of the loop amplifier                          *
*****************************************************************************
E_fw out 0 in fb A_DC/((1-s/(2*PI*p_1))*(1-s/(2*PI*p_2)))
*****************************************************************************
* definition of the transfer of the feedback circuit                        *
*****************************************************************************
E_fb fb 0 out 0 K_DC*(1-s/(2*PI*z_1))
*****************************************************************************
* definition of the output                                                  *
*****************************************************************************
.v out 0
*****************************************************************************
* if you want to see the properties of the loopgain, you have to define a   *
* loopgain reference variable (must be a controlled source).                *
*****************************************************************************
.l E_fw
*****************************************************************************
* Assign values to the parameters. The poles and zeros are in Hz;           *
* (see definitions of E_fw and E_fb).                                       *
*****************************************************************************
.p A_DC 100k
.p K_DC 0.1
.p p_1 -1k
.p p_2 -1M
.p z_1 -2.9M
*****************************************************************************
* here are the instructions                                                 *
*****************************************************************************
* The next instruction gives a symbolic expression for the gain (V_out/V_in)*
*****************************************************************************
.symbolic gain laplace
*****************************************************************************
* The next instruction gives a numeric expression for the gain (V_out/V_in) *
*****************************************************************************
.numeric gain laplace
*****************************************************************************
* The next instruction gives a table with poles and zeros of the gain       *
*****************************************************************************
.numeric gain pz
*****************************************************************************
* The next instruction gives the root-locus plot for A_DC from 0 to 100k    *
*****************************************************************************
.plot gain pz .step A_DC lin 0 100k 200 .range -10M 0 -5M 5M
*****************************************************************************
* The next instruction gives the root-locus plot for z_1 from -10M to -2.9M *
* This plot type is very useful for optimization of the high-frequency      *
* compensation.                                                             *
*****************************************************************************
.plot gain pz .step z_1 lin -10M -2.9M 50 .range -10M 0 -5M 5M
*****************************************************************************
* The next instruction gives a symbolic expression for the loopgain         *
*****************************************************************************
.symbolic loopgain laplace
*****************************************************************************
* The next instruction gives a numeric expression for the loopgain          *
*****************************************************************************
.numeric loopgain laplace
*****************************************************************************
* The next instruction gives a table with poles and zeros of the loopgain   *
*****************************************************************************
.numeric loopgain pz
*****************************************************************************
* The next instruction gives a polar plot of the loopgain. Notice that the  *
* DC value of the loopgain is negative. The 'Nyquist plot is rotated over   *
* degrees. As a result: the phase margin equals the phase!                  *
*****************************************************************************
.plot loopgain polar .f 2M 20M .step z_1 lin -5M -2M 4
*****************************************************************************
* The next instruction gives a dB magnitude plot of the loopgain.           *
*****************************************************************************
.plot loopgain db .f 10 10M .step z_1 lin -5M -2M 4
*****************************************************************************
* The next instruction gives a phase plot of the loopgain. Notice that the  *
* DC value of the loopgain is negative and SLiCAP maps the phase between    *
* +180 and -180 degrees.                                                    *
*****************************************************************************
.plot loopgain phase .f 10 10M .step z_1 lin -5M -2M 4
.end